rm.phs

Go to the documentation of this file.

// Port of 'rm' - remove files for GNU.
// 'rm' file removal program for Phasor.
//   Copyright (C) 2026 Daniel McGuire.
//
//   This program is free software: you can redistribute it and/or modify
//   it under the terms of the GNU General Public License as published by
//   the Free Software Foundation, either version 3 of the License, or
//   (at your option) any later version.
//
//   This program is distributed in the hope that it will be useful,
//   but WITHOUT ANY WARRANTY; without even the implied warranty of
//   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
//   GNU General Public License for more details.
//
//   You should have received a copy of the GNU General Public License
//   along with this program.  If not, see <https://www.gnu.org/licenses/>.
 
include_stdio();
include_stdfile();
include_stdsys();
 
fn show_help() -> void {
    puts("Usage: rm [OPTION]... FILE...");
    puts("Remove (unlink) the FILE(s).");
    puts("");
    puts("Options:");
    puts("  -f, --force              ignore nonexistent files");
    puts("  --help                   display this help and exit");
    puts("  --version                output version information and exit");
}
 
fn show_version() -> void {
    puts("rm (Phasor coreutils) 0.1");
    puts("License GPLv3+: GNU GPL version 3 or later");
    puts("This is free software: you are free to change and redistribute it.");
    puts("There is NO WARRANTY, to the extent permitted by law.");
}
 
fn main() -> int {
    var argc = sys_argc();
    if (argc < 2) {
        putf("Usage: %s FILE...", sys_argv(0)); puts("");
        puts("Remove FILE(s).");
        return 1;
    }
 
    var force = false;
    var i = 1;
    
    while (i < argc) {
        var arg = sys_argv(i);
        
        if (arg == "--") {
            i = i + 1;
            break;
        }
        
        if (arg == "-f" || arg == "--force") {
            force = true;
            i = i + 1;
            continue;
        }
        
        if (arg == "--help") {
            show_help();
            return 0;
        }
        
        if (arg == "--version") {
            show_version();
            return 0;
        }
        
        if (arg.startsWith("-")) {
            puts("rm: invalid option");
            puts("Try 'rm --help' for more information.");
            return 1;
        }
        
        break;
    }
 
    var error = false;
    while (i < argc) {
        var file = sys_argv(i);
        if (!frm(file)) {
            if (!force) {
                puts("rm: cannot remove file");
                error = true;
            }
        }
        i = i + 1;
    }
 
    if (error) return 1;
    return 0;
}
 
shutdown(main());