phasor_help.phs

Go to the documentation of this file.

using("stdio", "stdsys", "stdstr", "stdtype", "stdfile", "stdmeta");
 
fn getDocCmd(part: string, type: int) -> string {
    var sb = sb_new();
    var os = sys_os();
    if (os == "win32") {
        sb_append(sb, "C:/Program%20Files/Phasor%20Programming%20Language/man/man");
        sb_append(sb, type);
        sb_append(sb, "/");
        sb_append(sb, part);
        sb_append(sb, ".");
        sb_append(sb, type);
        sb_append(sb, ".");
        sb_append(sb, "pdf");
        var path = sb_to_string(sb);
        sb_free(sb);
        return concat("\"start file:///", concat(path, "\""));
    } else if (os == "Linux" || os == "FreeBSD" || os == "UNIX" || os == "Darwin") {
        sb_append(sb, type);
        sb_append(sb, " ");
        sb_append(sb, part);
        var args = sb_to_string(sb);
        sb_free(sb);
        return concat("man ", args);
    } else {
        putf_error("Could not find documentation for %s(%d) on %s", part, type, os);
        shutdown(-1);
        return "cd ."; // noop if somehow reached
    }
}
 
fn showHelp(programName: string, exitCode: int) -> void {
    var winStr = "C:\\Program Files\\Phasor Programming Language\\man\\man<section>\n    \<page>.<section>.pdf";
    var unixStr = "/usr/share/man/man<section>/<page>.<section>(.gz)";
    var osxStr = "/usr/local/share/man/man<section>/<page>.<section>(.gz)";
    var osStr;
    var os = sys_os();
    if (os == "win32") {
        osStr = winStr;
    } else if (os == "Linux" || os == "FreeBSD" || os == "UNIX") {  
        osStr = unixStr;
    } else if (os == "Darwin") {
        osStr = osxStr;
    } else {
        osStr = "https://phasor-docs.pages.dev/man?f=<page>.<section>";
    }
 
    var helpStr = c_fmt(`
 
PHASOR-HELP(1)      Phasor %s      PHASOR-HELP(1)
 
NAME
    %s - open Phasor manual pages
 
SYNOPSIS
    %s <page> <section>
    %s --help
    %s -h
 
ARGUMENTS
    <page>
    The name of the manual page to open.
 
    <section>  
    The manual section number. This is an integer corresponding to 
    standard manual sections.  
 
EXAMPLES
    %s phasor 1
    Open the section 1 manual page for "phasor".
 
    %s phsb 5  
    Open the section 5 manual page for "phsb".  
 
    %s phasorstd_io 3  
    Open the section 3 manual page for "phasorstd_io".  
 
FILES
    %s
 
SEE ALSO
    MAN(1)
 
                              - 1 -
`, phs_version(), programName, programName, programName, programName, programName, programName, programName, osStr);
    if (exitCode == 0) puts(helpStr);
    else puts_error(helpStr);
    shutdown(exitCode);
}
 
fn main() -> int {
    if (sys_argc() == 3) {
        var page = to_string(sys_argv(1));
        var section = to_int(sys_argv(2));
        sys_shell(getDocCmd(page, section));
    } else {
        showHelp(fstem(sys_argv(0)), 1);
    }
    return 0;
}
 
shutdown(main());